ASP與資料庫結合

ASP與資料庫

資料庫簡介

Acess概要

SQL命令

ASP連接資料庫的方法

讀取/寫入資料庫的方法

ASP 語法

VB Script與JavaScript

ASP與Html表單
ASP與資料庫結合應用

ASP進階簡介

ASP/SQL命令小幫手

資料庫簡介

典型的資料庫是一個結構化的資料儲存檔案。
欄位(field)是資料庫中最小的單位，將有關係的欄位組合在一起使用就稱為紀錄(record)。
許多筆記錄集合起來就形成表格(table)。

http://www.miat.ee.isu.edu.tw/chen-web/89-1/Internet/ASP/02-1.htm

下圖是Access中的一個資料表的範例：

※縱走的每一欄就是所謂的欄位，橫走的就是一筆資料，而結合起來就稱為表格（資料表）。

Access概要

Access是一套個人使用的小型資料庫軟件，適合使用在內部網路或只有數個人共用資料庫的情況下使用，而Microsoft官方建議是儘量不以超過5個人為原則，而筆者個人嘗試結果在１０人同時使用都尚可應付，但再多的連結只會造成更多的「鎖死」，造成資料庫連結逾時、連接人數過多等的問題。
總而然之，Access適合初學資料庫練習使用或者需求不大的網路環境使用。
在開啟一個新的資料庫時，它會詢問你資料庫的實體檔案存放位置，請存放在有Web共用並有讀取／寫入權限的目錄（例如你們自己在系上的目錄。

Access的7大物件

在確認資料庫檔案儲存位置後，你應該會見到下圖：
Access的７個基本物件就是「資料表」、「查詢」、「表單」、「報表」、「資料頁」、「巨集」、「模組」等七個基本物件。
由於目前並不是完整的Access教學，如果對Access有興趣者請自行參考Microsoft Acess教學的書藉。
在此處我們只會用到「資料表」，其餘在ASP中沒有什麼意義。
所謂「資料表」即上面所述的表格(Table)，是構成資料庫的主要物件，一個資料庫可以擁有多個資料表。
一般的情況下皆會使用「使用設計檢視建立資料表」，按下後會見到下圖：

欄位名稱就是你要記錄該資料的名字（如例：姓名），欄位的取名沒有限制，但請不要使用一些關鍵、保留字完、中文等。
資料類型為該欄位中儲存資料的類型，在下一節將會詳細描述。
描述是供你自己作為備忘錄，你可以把該欄位的用途、意義等輸入在此，方便日後查閱。

常用資料類型簡介

文字：是最常用的資料類型，文字的資料可以儲存任意的資料。（可以相像成是一般的填入欄位<input type=text>）
備忘：是多多行的「文字」資料。（可以相像成是文字的填入欄位<textarea>...</textarea>）
數字：儲存單純屬於數字性質的類型，可以是整數、小數、負數、百分比等。
日期時間：是專門儲存日期或者時間類型的資料類型。
是／否：是存儲羅緝真／假的資料類型。（例如勾選式選項可用此類型<input type=checkbox>）
自動編號：是Access的一種特殊型態的類型，可以自動幫你生成連續不重覆的數列，常用於作為主鍵、流水號之用。

在每一種的資料類型，還有一些該欄位的屬性，每一種資料型態的屬性都大同小異，以下將以「文字」資料類型作為例子解析：

欄位大小：文字中特有的屬性，是描述該文字的總長度上限，超過上限則不予記錄。而數字中則是表示其是屬於那一種的數字型態，常用的是長整數及小數點，至於其他請參考Access的教科書。
格式：在絕大部分（文字、備忘沒有作用）的資料類型皆有的屬性，主要描述該類型的詳細格式，例如日期時間的表示方式、數字的記錄方法等。
輸入遮罩：常用於密碼的欄位，當你在輸入資料時，不想資料被使用者直接看到時可以修改「輸入遮罩」，使其變為***。
標題：在ASP中使用沒有什麼用處，但如果是設計Access程式時有一定用途，請自行參考Access的教科書。
預設值：你可以幫該欄位預先鍵一些常用的資料，讓使用者減少輸入。
驗証規則、驗証文字：針對使用者輸入的資料作驗証，符合則儲存，不常用的屬性，請自行參考Access的教科書。
必須有資料：就是規定該欄是否可以不輸入資料留白，但如無特殊要求，不建議使用。
索引：所謂的索引就是整個資料表依據的排序欄位，一個資料表中建議有一個主索引（通常以自動編號），另外亦可以建立其他副索引方便排序。（非必要，因為可以用SQL命令作排序。）

設計資料表之前的準備

在設計每一個資料庫前請先明確制度你所需要的資料表、其結構等等，並不建議在程式使用後再對資料庫結構作修改。
可以在一開始先想好大約需要設計何種資料庫，需要什麼欄位，每個欄位儲存資料的型態等先作詳細的考慮，然後再動手實作實料庫檔案。
以一般簡易型的通訊錄舉例：
- index (索引欄位)，「自動編號」，作為流水號編列的欄位。
- name (姓名欄位)，「文字, 30個字」，儲存成員名字的欄位。
- tel (電話欄位)，「文字, 30個字」，儲存成員電話號碼的欄位。
- address (住址欄位)，「文字, 255個字」，儲存成員住址的欄位。
實際的Access資料表如右圖所示。
在關閉時請將為資料表命名，建議命名成「contact」。

SQL命令

SQL是Structured Query Language的縮寫。
透過SQL命令，你可以直接操控資料庫，包括：新增、修改、刪除、排序等。
SQL命令是ANSI標準的語言。
SQL命令語法與英文類似，非常易於學習。
完整的SQL學習又可以成為另一門課了，所以我只會針對最常用的SQL命令「SELECT」作介紹。

SQL Select

Select是SQL命令中最常用的指令，是用以選取／查閱資料庫，基本的語法是「Select 欄位名稱 From 資料表」。
例如：Select * from userdb，意思是指從「userdb」資料表中選取「所有」(*)的欄位。見範例。
如果只要name資料的話，可以下這樣的命令：Select name from userdb，請看範例。

Where

Where為一切命令的「附屬條件」，可以附加在任何命令後，語法為「Where 欄位名稱羅輯判斷因子(=, >, <, Between, Like...　詳見下表) 資料數值」

羅輯判斷因子	描述
=	等於
<>	不等於
>	大於
<	小於
>=	大於或等於
<=	小於或等於
BETWEEN	在某一範圍內的值，使用方法：Between 資料１ AND 資料２，資料可為數字、文字，當以文字作為Between條件時會以英文字母順序排序理之。
LIKE	搜尋相似值，可以以%代表其餘的值，例如'a%'代表搜尋所有以a為首的值。如果寫成'%a%'則是代表搜尋所有包含a的值。

※注意：有部分SQL版本的 <>可能寫成!=

如果配合Select應用，例：select * from userdb where name='月月月'，其意指從「userdb」資料表中選取「所有」(*)的欄位，但其「name」要等於'月月月'。見範例。

And、Or

當條件判斷多於一個時，此時可以And或者Or做為連接。
例如：select * from userdb where name='月月月' and groups=2。見範例。
如果改為or：select * from userdb where name='月月月' or groups=2。見範例。
試著比較上述範例的結果應該可以理解and、or的使用方法及分別。

Order By

在SQL中需要排序時可以用此指令，此指令的使用方法：「Order By 欄位名稱」。
例如：select * from userdb order by address。見範例。
預設的排序方式均為由小至大。如果想由大至小排請用DESC。
例如：select * from userdb order by address desc。見範例。
如果排序想以參考多於一欄排序時，只需在第一欄後加上「, 第二欄」即可，例如：
select * from userdb order by address,groups。見範例。

ASP連接資料庫的方法

ASP連接資料庫操作時皆需透過ADO(ActiveX Data Objects)物件，通用的流程大約如下：
- 透過ADO物件建立資料庫連結。
- 打開資料庫。
- 建立ADO recordset物件。
- 打開recordset。
- 讀取、處理、新增、修改資料。
- 關閉recordset。
- 關閉資料庫。
連接方式可分為ODBC與非ODBC兩大類。但ODBC的適應性不佳，故不建議採用。

以Access資料庫舉例的連接方法（一）：

<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "資料庫檔案所在位置"
%>

以Access資料庫舉例的連接方法（二）：

<%
set db = Server.CreateObject("ADODB.Connection")
db.ConnectionString="DRIVER={Microsoft Access Driver (*.mdb)};DBQ="& Server.MapPath("資料庫檔案所在位置") &";DriverId=25;FIL=MS Access;MaxBufferSize=512;PageTimeout=50
db.Open
%>

其餘各種的資料庫連接方法參考：電腦寶箱。

讀取/寫入資料庫的方法 (ADO Recordset)

ADO RecordSet是讀取、處理資料庫的物件。使用時機必需在資料庫連接成功後，請參考下例：

<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "資料庫檔案所在位置"

set rs=Server.CreateObject("ADODB.recordset")
rs.Open SQL命令或者資料表, conn
%>

讀取recordset中資料的方法（一）：

<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open Server.MapPath("user.mdb")

set rs=Server.CreateObject("ADODB.recordset")
rs.Open "select * from userdb", conn

for each x in rs.fields
   response.write(x.name)
   response.write(" = ")
   response.write(x.value)
   response.write(" <br> ")
next
%>

觀看結果

讀取recordset中資料的方法（二）：

<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open Server.MapPath("user.mdb")

set rs=Server.CreateObject("ADODB.recordset")
rs.Open "select * from userdb", conn

response.write("index = " & rs("index") & "<br>")
response.write("name = " & rs("name") & "<br>")
response.write("tel = " & rs("tel") & "<br>")
response.write("address = " & rs("address") & "<br>")
response.write("groups = " & rs("groups") & "<br>")
%>

觀看結果

讀取所有資料的方法：

配合do while方式即可，請參考下列：

<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open Server.MapPath("user.mdb")

set rs=Server.CreateObject("ADODB.recordset")
rs.Open "select * from userdb", conn

do while not rs.eof
  for each x in rs.fields
     response.write(x.name)
     response.write(" = ")
     response.write(x.value)
     response.write(" <br> ")
  next
  response.write("<br>")
  rs.movenext
loop
%>

觀看結果

配合Html畫表格：

請直接看下例：

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open Server.MapPath("user.mdb")
set rs=Server.CreateObject("ADODB.recordset")
rs.Open "select * from userdb", conn
%>

<table border="1" width="100%">
<tr>
  <% for each x in rs.Fields
       response.write("<td>" & x.name & "</td>")
     next
  %>
</tr>
<%
do while not rs.eof
  response.write("<tr>")
  for each x in rs.fields
    response.write("<td>" & x.value & "</td>")
  next
  response.write("</tr>")
  rs.movenext
loop
%>
</body>
<html>

觀看結果

新增資料的方法：

需要新增資料時一定要配合「HTML表格」使用，此範例包含兩個檔案：

add_data.html

<html>
<body>
<form method="post" action="record_add.asp">
<table border=1 cellpadding=0 cellspacing=0>
<tr>
<td>姓名：</td><td><input name="name"></td>
</tr>
<tr>
<td>電話：</td><td><input name="tel"></td>
</tr>
<tr>
<td>住址：</td><td><input name="address"></td>
</tr>
<tr>
<td colspan=2><input type=submit value=確定></td>
</tr>
</table>
</form>
</body>
<html>

record_add.asp

<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open Server.MapPath("user.mdb")
set rs=Server.CreateObject("ADODB.recordset")
rs.Open "select * from userdb", conn , 1 , 2

rs.addnew
rs("name")=Request.form("name")
rs("tel")=Request.form("tel")
rs("address")=Request.form("address")
rs.update

response.redirect "read_fields_html.asp"
%>

觀看結果

上述第一個「add_data.html」是收集數據的Html檔。第二個「record_add.asp」是實際操作資料庫，加入資料的ASP程式。
在新增／修改資料時，recordset的「open」方法略為不同，後面個實際數字的意義下：
recordset物件.open SQL命令,資料庫接結物件,遊標狀態,鎖定狀態
在遊標狀態及鎖定狀態沒有宣告時會用預設值（只有讀取的權限），而上例中的 1,2是完全鎖死資料庫的開啟法，在沒有update動作之前其他人都無法使用資料庫，比較安全的寫入方法。
詳細遊標狀態及鎖定狀態各值所代表的意義請參考W3School -- Recordset Open
rs.addnew是開始新增資料的起始指令。
讀取、寫入或者修改欄位時，可以透過rs("欄位名字")作此動作。
完成後需以rs.update作正式寫入資料庫的動作（新增／修改皆需要）。
response.redirect是網址轉向的指令，使用此指令，可以令自身的網址轉到指定的網址。

通訊錄範例

本範例是使用上述的指令，綜合寫成一個通訊錄系統，請直接看範例。

資料參考：
W3School -- ADO Tutorial（英）
W3School -- SQL Tutorial（英）
網站建置百寶箱

Wrote by Kit Leong 2003